Force a SkyDrive sync

Using a symbolic link to add an unmoveable folder to SkyDrive means that changes in the source folder will not be automatically synchronized. This batch file will create a new folder in your SkyDrive folder. By doing so, it forces SkyDrive to scan your local SkyDrive folder for changes and update your files on the web.
@echo off
:: A batch file to modify a folder at SkyDrive or create a new one. 
:: Running this file will force a sync from the computer to SkyDrive. 
:: Written in August 2012 by Noel Burgess
:: Modified in November 2012 - thanks to *kashmiri* and DullGlow 
:: http://wlmail.wordpress.com/
:: ===============================================================
:: Find the user's SkyDrive folder and change directory to it
:: 
for /F "tokens=1,2,3 skip=1" %%i ^
in ('reg query HKCU\Software\Microsoft\SkyDrive /v UserFolder') ^
do (set "skydrivefolder=%%k")
cd %skydrivefolder%
:: 
:: Find the system date and time in ISO format. Create a string
:: consisting of the date/time group.
:: 
for /F "usebackq tokens=1,2 delims==" %%l in (`wmic os get ^ 
LocalDateTime /VALUE 2^>NUL`) do ^
if '.%%l.'=='.LocalDateTime.' set ldt=%%m
set ldt=%ldt:~0,4%.%ldt:~4,2%.%ldt:~6,2% %ldt:~8,2%.%ldt:~10,2%
:: 
:: If there is a folder whose name starts with "!", rename it
:: with a name in the format ! Date Time.
:: Starting with a '!' puts it at or near the top of the folder
:: list regardless of whether the list is sorted by Name or Date.
:: If no such folder exists, create it.
:: 
if exist "!*" goto exists
md "! %ldt%"
goto finito
:exists
for /D %%n in (!*) do ren "%%n"  "! %ldt%"
:finito
:: ===============================================================
:: 
:: Use Task Scheduler to create a task to run this script at the
:: same time each day and at regular intervals thereafter.
::
Follow

Get every new post delivered to your Inbox.